Hint

Описание

Hint - оператор вызова подсказки. Подсказка появляется в нижнем правом углу, чуть выше трея. Длительность 5 секунд. <br>Можно использовать параметры. Параметры устанавливают значения для:

• fontSize - размер шрифта
• fontColor - цвет шрифта
• posX posY - положение подсказки по оси XY
• width height - размер окна подсказки

<br>Круглые скобки обязательны, отсутствовать могут любые параметры, начиная с конца. Если в качестве параметра указана '-1' то этот параметр игнорируется, как если бы не был указан вовсе. Координаты могут быть отрицательными, за исключением '-1'.

Синтаксис

Привязка к окну: нет. <br>Работа со свернутым окном: да.

hint любой текст
или
hint ([fontSize fontColor [posX posY [width height]]] (any text))

Примеры

// Пример 1
hint Пример сообщения // простое сообщение

// Пример 2
hint (12 255 0 0 -1 -1 ( #x, #y / #xa, #ya - цвет #color )) // а здесь используются переменные

// Пример 3
set $a Сообщение
hint (20 clPurple 500 500 -1 -1 ($a))

// Пример 4
set #a #a + 1
set #b #b + 2
set #c #c + 3
hint #a \n#b \n#c

// Пример 5
set delimiter '\n'                  //установить разделитель \n - перенос строки
set %a [1 1] Адрес: г. Москва
set %a [1 2] Телефон: 8(495)123-45-67
set %a [1 3] ICQ: 123456789
hint %a [1]                          //вывести сообщение с переносом строк 
End_script

// Пример 6
call hint1          //переход в процедуру
proc hint1
    hint (20 clPurple 500 500 -1 -1 (Сообщение из процедуры))      //закроется при выходе из процедуры
    wait 500    
end_proc
End_script

// Пример 7 
init_arr %a (1) hour : min : sec
hint (20 clRed 500 500 -1 -1 (%a [1]))      // вывести текущее время

// Пример 8
// Чтобы убрать сообщение, можно вывести его за пределами экрана
hint (24 clred 500 500 (TEXT))   // показать сообщение
wait 2000                        // ждать 2 секунды
hint (12 clred 1920 0 ())        // показать сообщение за пределами экрана
End_script

Смотрите также

Msg <br>Logging <br>Alarm

История развития

2.21 <br>Добавил вывод сообщения в виде всплывающей подсказки в правом нижнем углу экрана:

'hint <text>'

Не останавливает скрипт, исчезает через 4 секунды, всплывает поверх всех окон. Символы '|' и '/n' являются символами перевода строки. Длина текста ограничена 255 символами.

2.22 <br>Поправил 'hint'. Устранил мигание, ускорил в 4 раза. Добавил в 'hint' возможность задания некоторых параметров, в связи с этим слегка изменился синтаксис. Старый вариант по прежнему работает:

'hint ([fontSize fontColor [posX posY [width height]]] (any text))'

Круглые скобки обязательны, отсутствовать могут любые параметры, начиная с конца. Если в качестве параметра указана '-1' то этот параметр игнорируется, как если бы не был указан вовсе. Координаты могут быть отрицательными, за исключением '-1'. <br>Переделал команду 'hint', теперь у каждого скрипта свой хинт. Вывод хинтов из процедур поддерживается, но не рекомендуется. при этом происходит закрытие хинта не по таймеру, а по выходу из процедуры.

2.23 <br>Исправил вывод сообщений, содержащих круглые скобки, в команде 'hint'.

2.27.2 <br>Исправил вывод переменных в команде 'hint'.

2.32 <br>Добавил несколько ненужных зарезервированных переменных обозначающих цвет: 'clAqua', 'clBlack', 'clBlue', 'clDkGray', 'clFuchsia', 'clGray', 'clGreen', 'clLime', 'clLtGray', 'clMaroon', 'clNavy', 'clOlive', 'clPurple', 'clRed', 'clSilver', 'clTeal', 'clWhite', 'clYellow'.

2.39 <br>Исправил размер и цвет шрифта "по-умолчанию" в команде 'hint'.